String Functions Performance Considerations

I’ve been doing some tests and I see Instr$ in LotusScript is still a lot slower when you start searching in the middle of the string. I wrote an SPR about this sometime back.

The same is true of Mid$ – I wrote a timing test that uses Mid$ to get the 1st character of a string as opposed to the 27000th. The latter takes much longer, and I don’t understand why. According to the help docs it’s two bytes per character, so it should be trivial to determine the location of a character from its number position.

Timing test results

• 0.0008ms – Mid$(x, 1, 1)
• 0.0566ms – Mid$(x, 27000, 1)
• 0.0010ms – instr$(1, t, “x”) (where “x” occurs at position 1)
• 0.2924ms – instr$(27000, t, “x”) (where “x” occurs at position 27000)

What’s going on here? How can it take so much longer to access a string starting at a later position? It must be looping to get to the right starting position instead of just calculating the offset — character position X 2.

Do we care?

Generally, performance of in-memory operations like this is swamped by the much slower things scripts normally spend a lot of time doing, like accessing documents and views. But sometimes it really matters — like when finding string differences in the compareDBs application, for instance. And this seems like an easy fix, worth doing.

As they say in the political ads, “Contact your representative and ask them to do something about this.”

Notes: Performance testing technique

To do this performance test. I created a class PerfTimer. This is more complex than it needs to be for a “quick and dirty” test, but it’s adaptable to other situations, particularly where you don’t have a good idea how long something might take within an order of magnitude. “Let’s do this a million times and see how long it takes” isn’t a great idea when you’re not sure you won’t be waiting four hours for it to finish. By setting the testing time rather than the number of repetitions, we get a predictable experience — it won’t take much longer than your target time, but there will be enough repetitions to be meaningful without having to hunt around for a how many repetitions will be enough for the signal to exceed the noise. Here’s the code:

%REM
	Class PerfTimer
	Constructor: New PerfTimer(seconds)

	Description: A timer for performance testing. The timer will run for a specified number of seconds and count how many times something repeated during that time.
		You can run up to 10 different scenarios for comparison purposes, getting the results at the end. The sequence of operations is:
		 - Create a PerfTimer that will run for a stated number of seconds.
		 - "Start" the timer, supplying the name of the test scenario you're timing.
		 - Use a loop of this form:
		 
		 	Dim pt as New PerfTimer(15) ' we'll count how many times we can do something in 15 seconds.
		 	pt.start "Scenario 1"
			Do
				' Insert operation you're timing here.
			Loop Until pt.isdone
			pt.start "Scenario 2"
			Do
				' Insert operation you're comparing to the first.
			Loop Until pt.isdone
			Msgbox pt.Result ' show timing results in seconds.
		
		Note: if the operation you're timing is pretty quick, it's a good idea to add an inner loop to repeat it (let's say) 1000 times,
			so the timing differences between scenarios aren't swamped by the performance testing overhead.
%END REM
Class PerfTimer
	z_timePer(10) As Double
	z_id(10) As String
	z_index As Integer
	z_curCount As Long
	z_targetTime As Single
	z_runtimeTarget As Single ' seconds
	z_startTime As Single

	Sub New(seconds As Integer)
		z_index = -1
		z_runtimeTarget = seconds
	End Sub
	
	%REM
		Sub start
		Description: Start a timer for a test run, specifying which code variant we're testing.
	%END REM
	Sub start(testName$)
		z_index = z_index + 1
		z_id(z_index) = testName
		z_curCount = 0
		Dim startTime As Single
		startTime = Timer
		Do
			z_startTime = timer
		Loop While startTime = z_startTime ' wait for timer to tick
		z_targetTime = z_startTime + z_runtimeTarget
	End Sub
	
	%REM
		Property Get isDone
		Description: Return True if timer target is reached, meanwhile counting how many times this routine is called.
	%END REM
	Property Get isDone As Boolean
		z_curCount = z_curCount + 1
		Dim tim As Single
		tim = Timer
		If tim >= z_targetTime Then ' use actual time elapsed to calculate rate.
			z_timePer(z_index) = (tim - z_startTime) / z_curCount
			isDone = True
		End If
	End Property
	
	%REM
		Property Get results
		Description: Return a list of test names and time per iteration.
	%END REM
	Public Property Get results As String
		Dim i%
		ReDim ans(0 To z_index) As String
		
		For i = 0 To z_index
			ans(i) = Format(z_timePer(i), "0.########") & " - " & z_id(i) 
		Next
		results = Join(ans, {
})
	End Property
End Class